* LMH6642Q
*****************************************************************************
* (C) Copyright 2012 Texas Instruments Incorporated. All rights reserved.
*****************************************************************************
** This model is designed as an aid for customers of Texas Instruments.
** TI and its licensors and suppliers make no warranties, either expressed
** or implied, with respect to this model, including the warranties of
** merchantability or fitness for a particular purpose.  The model is
** provided solely on an "as is" basis.  The entire risk as to its quality
** and performance is with the customer.
*****************************************************************************
*
** Released by: WEBENCH(R) Design Center, Texas Instruments Inc.
* Part: LMH6642Q
* Date: 6/14/2012
* Model Type: All In One
* Simulator: SPICE
* Simulator Version: N/A
* EVM Order Number: N/A
* EVM Users Guide: N/A
* Datasheet: SNOSC61A - January 18, 2012
*
* Model Version: 1.0
*
*****************************************************************************
*
* Updates:
*
* Version 1.0 : Release to Web
*
*****************************************************************************
* Notes:
* 
* This model can be used for both LMH6642 and LMH6642Q
*
*
*		    LMH6642Q SPICE MODEL PERFORMANCE
*
*	MODEL FEATURES INCLUDE OUTPUT SWING, OUTPUT CURRENT THRU
*	THE SUPPLY RAILS, GAIN AND PHASE, GAIN CHANGE WITH LOAD,
*	SLEW RATE, COMMON MODE REJECTION WITH FREQUENCY EFFECTS,
*	POWER SUPPLY REJECTION ON BOTH RAILS WITH FREQUENCY
*	EFFECTS, INPUT VOLTAGE NOISE WITH 1/F,INPUT CURRENT NOISE
*	WITH 1/F, AND QUIESCENT	SUPPLY CURRENT. MODEL PERFORMANCE
*	CHANGES ONLY SLIGHTLY WITH SUPPLY AS PER DATA SHEET.
*
*	MODEL TEMP RANGE IS -55 TO +125 DEG C.
*
*	NOTE THAT MODEL IS FUNCTIONAL OVER THIS	RANGE BUT NOT ALL
*	PARAMETERS TRACK THOSE OF THE REAL PART.
*
*
*	SPEC			MACRO		DATA
*				MODEL		SHEET
*
*	SUPPLY VOLT RANGE	3 TO 12		3 TO 12		VOLTS
*
*	AVOL CHANGES W LOAD	YES		YES
*
*	INPUT COMMON MODE	(V+)-1		(V+)-1		VOLTS
*	VOLTAGE RANGE		TO (V-)-1	TO (V-)-1
*
*	PHASE REVERSAL IF	NO		NO
*	DRIVEN PAST INPUT
*	COMMON MODE VOLT
*	RANGE
*
*	INPUT CLAMP DIODES	YES		YES
*
*	PNP INPUT STAGE		YES		YES
*
*	COLLECTOR OUTPUT	YES		YES
*
*	CMRR FREQ EFFECTS	YES		YES
*
*	PSRR FREQ EFFECTS	YES		YES
*
*	
*	INPUT VOLTAGE NOISE	17		17		NV/RHZ
*
*	INV INPUT I NOISE	0.9		0.9		PA/RHZ
*
*	VOLT NOISE 1/F 1KHZ	48		48		NV/RHZ
*
*	INV IN INOISE 1/F 1KHZ  7.9		3.3		PA/RHZ
*
*	INPUT BIAS CURRENT	1.6		1.7		UA
*
*	VOS			 1		 1		MV
*
*	SLEW RATE 		125		125		V/US
*
*	SWING AT 10MA		+100,-150	+-90		MV
*
*	SWING AT 50MA		+300,-350	+-250		MV
*
*	SWING AT 100MA		+590,-630	+-750		MV
*
*	ICC			2.7		2.7		MA
*
*	+PWR SPLY REJ		71		71		DB
*
*	-PWR SPLY REJ		71		71		DB
*
*	COMMON MODE REJ		93		93		DB
*
*	AVOL @ RL=2K		100		100		DB
*
*	AVOL ZERO CROSS		78		58		MHZ
*
*	AC ZO AT 1KHZ		0.011		0.02		OHM
*
*	AC ZO AT 10KHZ		0.015		0.02		OHM
*
*	AC ZO AT 100KHZ		0.07		0.05		OHM
*
*	AC ZO AT 1MHZ		0.6		0.3		OHM
*
*	AC ZO AT 10MHZ		6.7		4.5		OHM
*
*	AC ZO AT 100MHZ		47		100		OHM
*
*	OUPUT CURRENT LIMIT +	114		115		MA
*
*	OUPUT CURRENT LIMIT -	142		145		MA
*
*	BANDWIDTH @ AVCL= +1	125		130		MHZ
*
*	PEAKING @ AVCL= +1	0.15/54		0.2/60		DB/MHZ
*
*	BANDWIDTH @ AVCL= +2	81		60		MHZ
*
*	PEAKING @ AVCL= +2	0.4/37		1/30		DB/MHZ
*
*	BANDWIDTH @ AVCL= +10	9.7		 7		MHZ
*
*	PEAKING @ AVCL= +10	NONE/-		NONE/-		DB/MHZ
*
*
* PINOUT ORDER -IN +IN VCC VEE OUT
* PINOUT ORDER  2   3   7   4   6
*****************************************************************************
.SUBCKT LMH6642Q 2 3 7 4 6
C4 30 94 7E-20
R50 94 14 700E3
C10 20 96 0.35E-15
R52 96 0 20E3
CC2 14 30 0.0085E-12
E1 39 63 14 62 16
C8 45 0 1E-12
C9 2 0 1E-12
RC1 42 0 1E12
I1 7 46 175E-6
I2 5 4 50E-6
D2 18 0 DVM
I3 7 12 50E-6
C1 13 92 8E-12
D7 23 0 DVM
R1 14 13 100
I4 0 18 1.068E-4
R2 7 15 1
R3 4 16 1
R4 17 98 100
R5 19 97 100
R6 46 8 1
R7 7 21 500
R8 7 22 500
R9 24 80 500
R10 25 80 500
I8 0 23 1.068E-4
I5 26 7 20E-6
I6 80 27 20E-6
I7 28 29 13E-6
E3 3 45 23 18 7.8
D8 37 0 DIM
Q1 30 27 24 Q2M
Q2 14 27 25 Q2M
Q3 34 9 80 Q1M
Q4 9 9 80 Q1M
Q5 92 34 16 Q5M
Q8 34 17 4 Q1M
D9 40 0 DIM
I9 0 37 1.068E-4
Q26 12 12 31 Q1M
Q27 7 12 34 Q1M
Q28 92 8 15 Q28M
Q29 20 19 7 Q29M
Q30 5 5 32 Q29M
Q31 34 5 46 Q29M
Q32 30 26 21 Q33M
Q33 14 26 22 Q33M
Q34 33 28 29 Q29M
Q35 84 35 36 Q35M
Q36 83 2 38 Q35M
R11 33 36 135
R12 33 38 135
Q37 32 32 7 Q29M
Q38 31 31 4 Q1M
R13 20 41 100E3
M1 9 20 46 46 WPM
I10 0 40 1.068E-4
E2 41 39 42 43 1
V3 7 42 2
R14 7 43 10E6
R15 43 80 10E6
D1 46 44 D1M
V4 44 20 0.75
V6 35 45 1E-3
IQA 7 4 -1.00E-3
G3 2 45 40 37 2.3E-4
D3 35 7 D3M
D4 2 7 D3M
D5 64 35 D3M
D6 64 2 D3M
V7 7 29 0.2
G1 0 48 7 0 1
R17 49 48 1
L2 0 49 10E-6
R20 0 49 10
G2 22 21 48 0 7.8E-7
G9 0 57 4 0 1
R21 74 57 1
L5 0 74 12E-6
R22 0 74 120
G10 21 22 57 0 -7.8E-7
R34 81 82 1
L6 82 0 20E-6
R35 82 0 100
G11 21 22 81 0 2.6E-8
G12 0 81 33 0 1
R48 92 6 3
E5 97 7 7 15 -6.7
E6 98 4 16 4 4.85
VCM1 4 80 1.5
VCM2 84 25 0.55
VCM3 83 24 0.55
RN1 62 0 1E12
RN2 63 0 1E12
VF1 62 43 0.99
VF2 7 63 1.2
VCM4 64 4 -0.7
.MODEL Q1M NPN
.MODEL Q2M NPN (VAF=150)
.MODEL Q5M NPN (BF=1000 VAF=125)
.MODEL Q28M PNP (BF=165 VAF=100)
.MODEL Q29M PNP
.MODEL Q33M PNP (VAF=150)
.MODEL Q35M PNP (BF=406 KF=3E-17)
.MODEL WPM PMOS (KP=1E-3 VTO=-0.6)
.MODEL DVM D (IS=1E-16 KF=2.7E-15)
.MODEL DIM D (IS=1E-16 KF=4.5E-15)
.MODEL D1M D (IS=7E-14 M=0.45 N=2 TT=6E-09)
.MODEL D3M D (IS=3E-14)
.ENDS
* END LMH6642Q MODEL
