************************************************************************
* DP139 HSPICE run file
************************************************************************
************************************************************************
************************************************************************
* DISCLAIMER :
************************************************************************
*          Property of Texas Instruments Incorporated.  Unauthorized   *
*          reproduction and/or distribution is strictly prohibited.    *
*                                                                      *
*          This product is protected under copyright law.              *
*          Created 2005, (C) Copyright 2005, Texas Instruments Inc.,   *
*          All Rights Reserved                                         *
*                                                                      *
*          UNLESS THERE IS A SIGNED, WRITTEN AGREEMENT TO THE          *
*          CONTRARY, TEXAS INSTRUMENTS ("TI") IS PROVIDING THE SPICE   *
*          MODELS "AS IS" AND WITHOUT ANY WARRANTY, EXPRESSED OR       *
*          IMPLIED.  TI assumes no liability for:                      *
*          1) the accuracy of the SPICE models provided to your        *
*             company;                                                 *
*          2) the proper functioning of these SPICE models in your     *
*             design or for any resulting applications; or             *
*          3) infringement of patents, copyrights or intellectual      *
*             property rights resulting from your use of these         *
*             SPICE models.                                            *
*                                                                      *
*          TI provides SPICE Models as a service to our customers.     *
*          You and your company shall not distribute, sell or give     *
*          these models to anyone else without prior written           *
*          permission from TI.                                         *
*                                                                      *
*          TI reserves the right to make changes to our products or    *
*          to discontinue any semiconductor product or service         *
*          without notice, and advises our customers to obtain the     *
*          latest version of relevant information to verify, before    *
*          placing orders, that the information being relied on is     *
*          current.                                                    *
*                                                                      *
*          Please be aware that your receipt and use of the SPICE      *
*          information provided shall serve as acceptance of these     *
*          terms and conditions.  If you do not accept these terms,    *
*          you should return or destroy the SPICE models and any       *
*          other accompanying information immediately.                 *
*                                                                      *
*          Contact Texas Instruments at ATTN:DATA TRANSMISSIONS        *
************************************************************************
************************************************************************
************************************************************************
************************************************************************
*** Description of the circuit included in the netlist(top_dp139.inc):
***
*** The netlist contains all of the high speed Main Link I/Os (IN_Dxx,  
*** and OUT_DXX). 
*** Auxiliary signals(SDA__I2C, AUXN_I2C, I2C_SDA, I2C_SCL)
*** Many non high speed signals (HPDxx, SDAxx, SCLxx, OE_N, DDC_EN, HPD_INV)
*** are taken out of this netlist for ease of simulations and simplicity.
***
***  The following is a description of Pins/Signals:
***  
***
***  Signal                                                   Description
***
***   VCC                                               power (3.3V)
***   GND                                               ground
***   IN_D1P, IN_D2P, IN_D3P, IN_D4P                Main Link positive inputs
***   IN_D1N, IN_D2N, IN_D3N, IN_D4N                Main Link negative inputs
***   OUT_D1P, OUT_D2P, OUT_D3P, OUT_D4P               TMDS positive output
***   OUT_D1N, OUT_D2N, OUT_D3N, OUT_D4N               TMDS negative output
***   VSADJ                                    		Tmds output swing control (through external resistor)
***   SRC                                                Output rise/fall time setting
***   I2C_EN                                             When low, this pin is used for rise/fall time setting (w/ SRC pin) 
****************************************************************************************************************************
****************************************************************************************************************************

**********************************************************************
***********                 CIRCUIT CALL               ***************
**********************************************************************
XTOP net46 net44 GND GND net64 GND GND VCC OUT_D4P OUT_D4N OUT_D3P OUT_D3N
+OUT_D2P OUT_D2N OUT_D1P OUT_D1N IN_D4P IN_D4N IN_D3P IN_D3N IN_D1N IN_D2P
+IN_D1P IN_D2N SRC GND GND VSADJ GND I2C_EN GND TOP_DP139

****************************
*** Power Sources and ground
****************************
.PARAM vst=3.3
.PARAM v3p3=3.3

V1 VCC 0 DC=v3p3
V3 GND 0 DC=0


**************************************
*** DP inputs
**************************************
V12 IN_D1N 0 DC=0 AC 0 0 PULSE '550e-3*v3p3+200e-3' '550e-3*v3p3-200e-3' 0
+200e-12 200e-12 200e-12 800e-12
V11 IN_D1P 0 DC=0 AC 0 0 PULSE '550e-3*v3p3-200e-3' '550e-3*v3p3+200e-3' 0
+200e-12 200e-12 200e-12 800e-12
V28 IN_D3P 0 DC=0 AC 0 0 PULSE '550e-3*v3p3-200e-3' '550e-3*v3p3+200e-3' 0
+200e-12 200e-12 200e-12 800e-12
V29 IN_D4P 0 DC=0 AC 0 0 PULSE '550e-3*v3p3-200e-3' '550e-3*v3p3+200e-3' 0
+200e-12 200e-12 200e-12 800e-12
V30 IN_D2N 0 DC=0 AC 0 0 PULSE '550e-3*v3p3+200e-3' '550e-3*v3p3-200e-3' 0
+200e-12 200e-12 200e-12 800e-12
V27 IN_D2P 0 DC=0 AC 0 0 PULSE '550e-3*v3p3-200e-3' '550e-3*v3p3+200e-3' 0
+200e-12 200e-12 200e-12 800e-12
V31 IN_D3N 0 DC=0 AC 0 0 PULSE '550e-3*v3p3+200e-3' '550e-3*v3p3-200e-3' 0
+200e-12 200e-12 200e-12 800e-12
V32 IN_D4N 0 DC=0 AC 0 0 PULSE '550e-3*v3p3+200e-3' '550e-3*v3p3-200e-3' 0
+200e-12 200e-12 200e-12 800e-12

**************************************
*** TMDS output terminations 
**************************************
R11 VST OUT_D4P 50
R12 VST OUT_D2P 50
R8 VST OUT_D3P 50
R14 VST OUT_D1N 50
R9 VST OUT_D3N 50
R15 VST OUT_D1P 50
R10 VST OUT_D4N 50
R13 VST OUT_D2N 50
C15 OUT_D1P 0 1e-12
C8 OUT_D3P 0 1e-12
C9 OUT_D3N 0 1e-12
C12 OUT_D2P 0 1e-12
C14 OUT_D1N 0 1e-12
C11 OUT_D4P 0 1e-12
C13 OUT_D2N 0 1e-12
C10 OUT_D4N 0 1e-12

**************************************
*** VDADJ external resistor.
*** The value of this resistor can be adjusted 
*** to produce a desired TMDS output signal characteristics. 
************************************** 
R4 VSADJ GND 4.03e3

*********************************************
***TMDS output external voltage termination
********************************************
V5 VST 0 DC=vst

*********************************************
***Control pins
********************************************
V0 SRC 0 DC=v3p3
V2 I2C_EN 0 DC=0

******************
*** Process models
******************
.INCLUDE "nom.inc"


******************
*** Device model
******************
.INCLUDE top_dp139.inc


.TRAN 10e-12 5e-9 START=0.0

.OP

.TEMP 25
.OPTION
+    POST=1 POST_VERSION=2001
+    INGOLD=2
+    MEASOUT=1
+    PARHIER=LOCAL
+    SCALE=1e-6
+    ACCURATE
+    DELMAX=1e-9
+    probe
+    CONVERGE=1



.PROBE TRAN
+ V(IN_D1P)
+ V(IN_D1N)
+ V(IN_D2P)
+ V(IN_D2N)
+ V(IN_D3P)
+ V(IN_D3N)
+ V(IN_D4P)
+ V(IN_D4N)
+ V(OUT_D1P)
+ V(OUT_D1N)
+ V(OUT_D2P)
+ V(OUT_D2N)
+ V(OUT_D3P)
+ V(OUT_D3N)
+ V(OUT_D4P)
+ V(OUT_D4N)

.END
